Delphi Informant Complete 1995 - 2000/Delphi Informant Complete 1995 to 2000.iso/Delphi Informant Magazine Complete Works SOURCE CODE 1995.rar/1995/DEC/DI9512AC/fmain.pas

Pascal/Delphi Source File | 1995-08-18 | 6KB | 229 lines

unit Fmain;

interface

uses
  SysUtils, WinTypes, WinProcs, Messages, Classes, Graphics, Controls,
  Forms, Dialogs, StdCtrls, ExtCtrls,
  acList, acStream, Example, Buttons;


const
  LOG_FILE_NAME   = 'LOGGER.DAT';
  MAX_LOG_ITEMS   = 1024;
  LOG_UPDATE_FREQ = 20;  { seconds }

type
  TMainForm = class(TForm)
    LbLog: TListBox;
    GrpLogOptions: TGroupBox;
    ChLogResources: TCheckBox;
    ChLogMemory: TCheckBox;
    ChLogDiskSpace: TCheckBox;
    TmrLog: TTimer;
    HdLog: THeader;
    BtnStartStop: TBitBtn;
    BtnClear: TBitBtn;
    BtnSummarize: TBitBtn;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure TmrLogTimer(Sender: TObject);
    procedure BtnStartStopClick(Sender: TObject);
    procedure BtnClearClick(Sender: TObject);
    procedure BtnSummarizeClick(Sender: TObject);
  private
    { Private declarations }
    FOptions   : TOptions;    { Option settings }
    FLog       : TLog;        { List for log entries }
    FLogStream : TLogStream;  { Stream for data file }
    procedure ReadLog;
    procedure SaveLog;
    procedure AddToLog(const LogItem: TLogItem);
  public
    { Public declarations }
  end;

var
  MainForm: TMainForm;

implementation

{$R *.DFM}


{ ReadLog reads the options and the log from the data file }
procedure TMainForm.ReadLog;
begin
  if ( FileExists(FLogStream.Filename) ) then
    begin
    with  FLogStream  do
      begin
      OpenForInput;
      ReadObject(FOptions);
      ReadObject(FLog);
      Close;
      end;
    end;
end;

{ SaveLog saves the options and the log to the data file }
procedure TMainForm.SaveLog;
begin
  with  FLogStream  do
    begin
    OpenForOutput;
    SaveObject(FOptions);
    SaveObject(FLog);
    Close;
    end;
end;

procedure TMainForm.AddToLog(const LogItem: TLogItem);
begin
  if ( FLog.Count = MAX_LOG_ITEMS ) then FLog.DeleteIdx(0);
  FLog.Add(LogItem);
end;

procedure TMainForm.FormCreate(Sender: TObject);
begin
  { Set timer interval }
  TmrLog.Interval := 1000 * LOG_UPDATE_FREQ;

  { Create an options object }
  FOptions := TOptions.Create;

  { Create log list object, tie it to the log list box, }
  {   and give it ownership of the log entries.         }
  FLog := TLog.Create(LbLog.Items, True);

  { Create the log stream object for managing the app data file }
  FLogStream := TLogStream.Create(ExtractFilePath(Application.ExeName) + LOG_FILE_NAME);

  { Read in saved log }
  ReadLog;

  { Update controls }
  ChLogResources.Checked := FOptions.LogResources;
  ChLogMemory.Checked    := FOptions.LogMemory;
  ChLogDiskSpace.Checked := FOptions.LogDisk;
end;

procedure TMainForm.FormDestroy(Sender: TObject);
begin
  { Update controls }
  FOptions.LogResources := ChLogResources.Checked;
  FOptions.LogMemory    := ChLogMemory.Checked;
  FOptions.LogDisk      := ChLogDiskSpace.Checked;

  { Save log }
  SaveLog;

  { Free the log stream object }
  FLogStream.Free;

  { Free log list object. List will take care of deleting }
  {   the individual log entries.                         }
  FLog.Free;

  { Free options object }
  FOptions.Free;
end;


procedure TMainForm.TmrLogTimer(Sender: TObject);
var
  LogItem : TLogItem;
begin
  { Create log items and add them to the log. }
  { NOTE: We don't have to deal with the list box, just the list object. }
  if ( ChLogResources.Checked ) then AddToLog(TResourceLogItem.Create);
  if ( ChLogMemory.Checked )    then AddToLog(TMemoryLogItem.Create);
  if ( ChLogDiskSpace.Checked ) then AddToLog(TDiskLogItem.Create);

  { Scroll LB contents to show added items }
  LbLog.TopIndex := FLog.Count - 1;
end;

procedure TMainForm.BtnStartStopClick(Sender: TObject);
begin
  { Toggle timer enable to start/stop logging as appropriate }
  if ( TmrLog.Enabled ) then
    begin  { Disable it }
    TmrLog.Enabled := False;
    BtnStartStop.Caption := 'Start Logging';
    self.Caption := Application.Title + ' - Inactive';
    end
  else
    begin  { Enable it }
    TmrLog.Enabled := True;
    BtnStartStop.Caption := 'Stop Logging';
    self.Caption := Application.Title + ' - Active';
    { Fake an timer message so its obvious logging has started }
    TmrLogTimer(self);
    end;
end;

procedure TMainForm.BtnClearClick(Sender: TObject);
begin
  { Empty the log by removing everything from the list. }
  { NOTE: Don't need to access the list box directly.   }
  FLog.DeleteAll;
end;


procedure TMainForm.BtnSummarizeClick(Sender: TObject);
var
  MinResource : TResourceLogItem;
  MinMemory   : TMemoryLogItem;
  MinDisk     : TDiskLogItem;
  ItemIdx     : Integer;
  Item        : TLogItem;
begin
  { Report maximum resource usage }
  MinResource := nil;
  MinMemory   := nil;
  MinDisk     := nil;
  try
    MinResource := TResourceLogItem.Create;
    MinMemory   := TMemoryLogItem.Create;
    MinDisk     := TDiskLogItem.Create;
    { Scan log and track minimums }
    for ItemIdx := 0 to (FLog.Count - 1) do
      begin
      Item := FLog[ItemIdx];
      if ( Item is TResourceLogItem ) then
        begin
        if ( (Item as TResourceLogItem).Minimum < MinResource.Minimum ) then
          begin
          MinResource.Assign(Item);
          end;
        end
      else if ( Item is TMemoryLogItem ) then
        begin
        if ( (Item as TMemoryLogItem).FreeSpace < MinMemory.FreeSpace ) then
          begin
          MinMemory.Assign(Item);
          end;
        end
      else if ( Item is TDiskLogItem ) then
        begin
        if ( (Item as TDiskLogItem).FreeSpace < MinDisk.FreeSpace ) then
          begin
          MinDisk.Assign(Item);
          end;
        end;
      end;
    { Report results }
    ShowMessage('Maximum Resource Usage'#13#13 +
                MinResource.AsString + #13 +
                MinMemory.AsString + #13 +
                MinDisk.AsString);
  finally
    if ( Assigned(MinResource) ) then MinResource.Free;
    if ( Assigned(MinMemory)   ) then MinMemory.Free;
    if ( Assigned(MinDisk)     ) then MinDisk.Free;
    end;
end;

end.